Remote stops responding after Hibernate

[agerdin]

After waking up from Hibernate my remote stops working. To resolve I have to "restart" (unplug from power) my WinTV PVR-USB2 and then also restart GBPVR.

I am using the setting "use direct remote access" so I suspect the error somewhere in the pvr hardware and not related to GBPVR.

Any ideas anyone???

\\Agerdin

I have searched the forum since I vaguely remember asking about this before but I cannot seem to find anything.

[stefan]

I thought "use direct remote access" was only supported (working at all, actually) for the pvr-350 and the pvr-250... Could you, at least for fun and testing, go "back" to using ir32.exe and see if that helps? Btw, why don't you use the ir32.exe?

[agerdin]

No, it works just fine with the pvrusb2. Reason for using "use direct access.." is related to the focus problem and since we are using our htpc as a home computer as well it helps when one family member is using the computer at the same time another one is watching TV.

I will try with ir32.exe but for that there is the app gbpvrwake.exe to remedy if anything stops responding after hibernation or standby.

\\Agerdin

[stefan]

No, it works just fine with the pvrusb2. Reason for using "use direct access.." is related to the focus problem and since we are using our htpc as a home computer as well it helps when one family member is using the computer at the same time another one is watching TV.

Gotcha. I think someone has made adjustments to ir.ini to fix that, but I don't know how well it works.

I will try with ir32.exe but for that there is the app gbpvrwake.exe to remedy if anything stops responding after hibernation or standby.

Exactly, that's what I wanted to get to next Or if you search for wake.cmd, there is a utility for restarting the pvr-350... maybe you could adjust that to restart your pvrusb2, and possibly also gbpvr if needed.

[stefan]

This is the post I was referring to. It's from the old board, so it looks like crap, but I think it still works. At least you might be able to get some ideas how to use devcon and stuff Lycka till

http://forums.gbpvr.com/showpost.php?p=599&postcount=45

[agerdin]

Cool, thaks Stefan,

So if I understand you correct I would try to modify this to fit the pvr usb 2 and then wake.cmd is called from gbpvrwake.exe. This will then restart my pvr and gpbvr and I can still continue to use "direct access..."?

\\Agerdin

[stefan]

That's my idea. I don't know if it will work, though. You'll have to do the testing

[agerdin]

Stefan, do you have a working wake.cmd for your 350, that I can start working with? I can not find it anywhere as a file.

\\Agerdin

[stefan]

Sorry, no I don't use wake.cmd anymore. But you should be able to to copy the text below into a file you create with notepad or whatever. Name the file wake.cmd, and make sure notepad doesn't add the extension .txt

Code:

ECHO OFF
REM This batchfile is executed in the first seconds
REM after waking the machine from hibernation.

REM This will re-activate the tv-out after hibernation
REM Version 0.3, 20040907 by MaBo
REM You can contact me at the GBPVR forums

REM changes:
REM 0.3.1: minor fixes. Now the recording service and ir.exe are
REM restarted also when restarting the pvr350 failed.
REM 0.3: now all in one file: wake.cmd
REM check whether a version of wake.cmd is already running

REM first check whether another version is running
SET checkfile=c:\syslog\wakingtvout.txt

IF EXIST %checkfile% GOTO EXIT

echo waking started > %checkfile%

REM An entry to the logfile is generated.
REM define the path to your system logfile here:
set logfile=c:\syslog\syslog.txt
REM If you don't want a logfile, please remove all lines containing
REM %logfile% in the file below

echo Wake from hibernation >> %logfile%
date /t >> %logfile%
time /t >> %logfile%
pushd "C:\Program Files\DevCon"
ECHO OFF

REM In order to restart the pvr350, it should not be in use.
REM Therefore, the remote control program has to be stopped
REM modify the path when you have not made a default install.
"C:\Program Files\WinTV\Ir.exe" /QUIT

REM Then the GB-PVR recordingservice has to be stopped.
REM This will stop any running recordings!!
REM This is assumed to be safe, as the computer has just
REM woken from hibernation/standby. So it was idle.
net stop "GB-PVR Recording Service"
REM echo Recording service stopped >> %logfile%
REM date /t >> %logfile%
REM time /t >> %logfile%

REM Then the program devcon is called to do the actual restarting
REM devcon.exe can be downloaded from microsoft.com
devcon.exe restart PCI\VEN_4444^&DEV_0803
REM the entire identification of the PVR 350 was
REM in my case: PCI\VEN_4444&DEV_0803&SUBSYS_40000070& REV_01\3&61AAA01&0&70
REM However, the &-signs posed problems.
REM By using only PCI\VEN_4444, any pvr250's are probably restarted as well.

IF ERRORLEVEL 3 GOTO SYNTAX
IF ERRORLEVEL 2 GOTO FAILURE
IF ERRORLEVEL 1 GOTO REBOOT
IF ERRORLEVEL 0 GOTO SUCCES

:SUCCES
echo pvr350 restarted succesfully >> %logfile%
date /t >> %logfile%
time /t >> %logfile%
GOTO END

:REBOOT
REM The pvr350 could not be restarted. Probably because it was in use
REM by some program. A reboot is needed.
echo The pvr350 could not be restarted. Reboot required >> %logfile%
date /t >> %logfile%
time /t >> %logfile%
REM You could add a command here to automatically reboot your machine.
GOTO END

:FAILURE
REM The pvr350 could not be restarted at all.
echo pvr350 could not be restarted succesfully >> %logfile%
date /t >> %logfile%
time /t >> %logfile%
GOTO END

:SYNTAX
REM Syntax error.
echo There is a syntax error in wake.cmd >> %logfile%
date /t >> %logfile%
time /t >> %logfile%
GOTO END

:END
REM The statements below are always performed. Even when
REM errors have occured.
REM Restart the recordingservice
net start "GB-PVR Recording Service"
REM echo Recording service started >> %logfile%
REM date /t >> %logfile%
REM time /t >> %logfile%

REM Restart remote control
START C:\Progra~1\WinTV\Ir.exe /QUIET
REM remove the checkfile to enable new restarts
REM start gbpvr.exe
del %checkfile%

popd
:EXIT
REM Commands below are performed, even when another wake.cmd is busy.
EXIT

[agerdin]

excellent, one last question for now. Where would I need to go to find the eqvivialent of PCI\VEN_4444 for my usb2 device??? I have no idea where to start. Just thought if you know. Is it from device manager?

See mobos description below.

Code:

REM the entire identification of the PVR 350 was
REM in my case: PCI\VEN_4444&DEV_0803&SUBSYS_40000070& REV_01\3&61AAA01&0&70
REM However, the &-signs posed problems.
REM By using only PCI\VEN_4444, any pvr250's are probably restarted as well.

Thanks for your help

\Agerdin