Tool to merge tags in XMLTV files

[agerdin]

Hi,

Does anyone know of any program/tool that can be used to merge tags in XMLTV files. What I am looking for is to move information from tags such as actor, year, episode, aspect, etc into the desc tag which is supported by GBPVR.

Let me know if anyone has any ideas.

\\Agerdin

[Koenie]

Ton wrote a little progam called epgfilter. Have a look at this threat:
http://forums.nextpvr.com/showthread.php...=epgfilter

[agerdin]

Ton wrote a little progam called epgfilter. Have a look at this threat:
http://forums.nextpvr.com/showthread.php...=epgfilter

Looks promising, but I can not see where it may be downloaded from. Checked both the thread and wiki???

\\Agerdin

[Wim Fabri]

you can use an xslt file to do this. I use msxsl.exe to process it. (you can download it from microsoft)

xmltv.xslt :

Code:

<xsl:stylesheet version = '1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
<xsl:output method="xml" indent="yes" encoding="UTF-8"/>

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()" />
</xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme">
<xsl:copy>
<xsl:apply-templates select="@*" />
<xsl:apply-templates select="title" />
<xsl:apply-templates select="sub-title" />
<xsl:apply-templates select="icon" />
<xsl:apply-templates select="category" mode="m1"/>
<desc>
<xsl:apply-templates select="episode-num" />
<xsl:apply-templates select="desc" />
<xsl:apply-templates select="credits" />
<xsl:apply-templates select="rating" />
<xsl:apply-templates select="country" />
<xsl:apply-templates select="date" />
</desc>
</xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme/title">
<xsl:copy><xsl:apply-templates select="@*|node()" /></xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme/sub-title">
<xsl:copy><xsl:apply-templates select="@*|node()" /></xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme/icon">
<xsl:copy><xsl:apply-templates select="@*|node()" /></xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme/category" mode="m1">
<xsl:copy><xsl:apply-templates select="@*|node()" /></xsl:copy>
</xsl:template>

<xsl:template match="/tv/programme/episode-num">
<xsl:text>Episode </xsl:text><xsl:value-of select="." />
<xsl:choose>
<xsl:when test="not(../category) and not(../country) and not(../date)"><xsl:text>
</xsl:text></xsl:when>
<xsl:otherwise><xsl:text> | </xsl:text></xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="/tv/programme/category" mode="m2">
<xsl:value-of select="." />
<xsl:choose>
<xsl:when test="not(../country) and not(../date)"><xsl:text>
</xsl:text></xsl:when>
<xsl:otherwise><xsl:text> | </xsl:text></xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="/tv/programme/country">
<xsl:text>Land : </xsl:text>
<xsl:value-of select="." />
<xsl:choose>
<xsl:when test="not(../date)"><xsl:text>
</xsl:text></xsl:when>
<xsl:otherwise><xsl:text></xsl:text></xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="/tv/programme/date">
<xsl:text> - Jaar : </xsl:text>
<xsl:value-of select="." /><xsl:text>
</xsl:text>
</xsl:template>

<xsl:template match="/tv/programme/desc">
<xsl:value-of select="." /><xsl:text>
</xsl:text>
</xsl:template>

<xsl:template match="/tv/programme/credits">
<xsl:apply-templates select="presenter" />
<xsl:apply-templates select="guest" />
<xsl:apply-templates select="producer" />
<xsl:apply-templates select="director" />
<xsl:apply-templates select="actor" />
<xsl:apply-templates select="writer" />
</xsl:template>

<xsl:template match="/tv/programme/credits/presenter">
<xsl:if test="position()=1">Moderation: </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>
<xsl:template match="/tv/programme/credits/guest">
<xsl:if test="position()=1">Te Gast : </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>
<xsl:template match="/tv/programme/credits/producer">
<xsl:if test="position()=1">Van : </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>
<xsl:template match="/tv/programme/credits/director">
<xsl:if test="position()=1">Regie : </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>
<xsl:template match="/tv/programme/credits/actor">
<xsl:if test="position()=1">Met : </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>
<xsl:template match="/tv/programme/credits/writer">
<xsl:if test="position()=1">Boek : </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>

<xsl:template match="/tv/programme/rating">
<xsl:if test="@system='FSK'">FSK: <xsl:value-of select="value/." /></xsl:if>
</xsl:template>

<xsl:template name="comma"><xsl:if test="not(position()=last())">, </xsl:if></xsl:template>
<xsl:template name="newline">
<xsl:if test="position()=last()">
<xsl:text>
</xsl:text>
</xsl:if>
</xsl:template>

</xsl:stylesheet>

[agerdin]

Wim, thats exactly what I need. Is there anywhere a description of the stylesheet. My XML knowledge is limited. I can always try my way forward.

Many Thanks

\\Agerdin

[agerdin]

Wim, I got it to work and it was exactly what I needed. However, I have 2 questions,

1. In my XMLTV file I have 2 entries for episode-num and I want the stylesheet to exclude one of them (the first one) but I can not figure out how to do that.

Code:

<episode-num system="xmltv_ns">2004 . 13/24 . </episode-num>
    <episode-num system="onscreen">Del 14 av 24 säsong 2005</episode-num>

2. How can I use Swedisch characters (å, ä, ö) for literals in the stylesheet, msxsl.exe issues an error when using these characters.

Code:

<xsl:template match="/tv/programme/credits/actor">
<xsl:if test="position()=1">Skådespelare: </xsl:if>
<xsl:value-of select="." />
<xsl:call-template name="comma"/>
<xsl:call-template name="newline"/>
</xsl:template>

Thanks

\\Agerdin

[stefan]

Try changing encoding from "UTF-8" to "iso-8859-1" for å,ä,ö.

[stefan]

Don't know whether it's case sensitive, by the way. Maybe it should be "ISO-8859-1".

[agerdin]

Tried that already, but with no luck. The problem is not with åäö in the xmltv file but rather in the stylesheet itself.


Header of my stylesheet:

Code:

<xsl:stylesheet version = '1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
<xsl:output method="xml" indent="yes" encoding="ISO-8859-1"/>

Thanks anyway Stefan,

\\Agerdin

[stefan]

Ah, gotcha. Don't know the answer, though. We certainly use å,ä,ö in our stylesheets, but we don't use the msxsl exe, though. And something tells me you're not willing to setup an entire tomcat/cocoon solution